***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 22, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD60N04-AU   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = 1.95		 kp = 85.5	)
.model  dds   d(
+   is = 6.200e-12	  n = 1.039		   rs = 4.089e-3
+   eg = 1.092	     trs1 = 3.018e-2 )
.model  dbody d(
+   is = 6.200e-12	  n = 1.039		   rs = 4.089e-3
+  cjo = 4.736e-10	  m = 5.735e-1	   vj = 3.905e-1
+   bv = 44			ibv = 250e-6	 tbv1 = 9.365e-4	
+   tt = 25n)
.model  inter  nmos(
+  vto = 0			 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 6.734e-10	  m = 4.364e-1	   vj = 5.780e-1)
.param
+  cgs = 2.343e-9		cgd = 6.290e-10
+   rd = 3.300e-3		 ra = 1.000e-3	  trd1 = 9.575e-3		trd2 = 8.085e-6
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.60 ),
+ (2.50 , 2.30 ),
+ (2.70 , 2.45 ),
+ (3.00 , 2.65 ),
+ (3.10 , 2.75 ),
+ (3.20 , 3.00 ),
+ (3.50 , 4.05 ),
+ (4.00 , 5.10 ),
+ (4.50 , 6.00 ),
+ (5.00 , 6.85 ),
+ (6.00 , 8.40 ),
+ (7.00 , 9.60 ),
+ (8.00 ,10.78 ),
+ (10.0 ,11.95 ),
+ (20.0 ,11.96 ),
+ (22.0 ,11.96 ))
egt	  1  2t   value = {6.527e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1},{trd2}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
